Disable Alt+TAB, win key, ctrl esc key

Question

nemzmiyaw 0 Newbie Poster

13 Years Ago

i want to disable the Alt Tab, windows key, ctrl esc key.

FOr my Log On Security that start up in coomputer like windows log on.

Thanks for the help. Try to search hours for this but i cannot find the right solution

im using vb.net 2005 and OS is Vista.

vb.net

9 Contributors
10 Replies
6K Views
4 Years Discussion Span
Latest Post 8 Years Ago Latest Post by adeministrator

Unhnd_Exception

13 Years Ago

You can set up a low level hook to do that.

Heres an example that will disable the above.

You may have to go to Project / Properties / Debug and uncheck Enable the Visual Studio Hosting process for it to work while running in Visual Studio.

'Using the Class

Public Class Form1

    Private Sub Form1_HandleCreated(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.HandleCreated
        KeyboardJammer.Jam()
    End Sub

    Private Sub Form1_HandleDestroyed(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.HandleDestroyed
        KeyboardJammer.UnJam()
    End Sub

End Class

The Class

Imports System.Runtime.InteropServices
Imports System.Reflection

Public Class KeyboardJammer

    Private Delegate Function HookCallback(ByVal nCode As Integer, ByVal wParam As Integer, ByVal lParam As IntPtr) As Integer
    Private Shared HookDelegate As HookCallback
    Private Shared HookId As Integer
    Private Const Wh_Keyboard_LL As Integer = 13
    Private Const Vk_Tab As Integer = 9
    Private Const Vk_Escape As Integer = 27

    Private Shared Function KeyBoardHookProc(ByVal nCode As Integer, ByVal wParam As Integer, ByVal lParam As IntPtr) As Integer
        'All keyboard events will be sent here.

        'Don't process just pass along.
        If nCode < 0 Then
            Return CallNextHookEx(HookId, nCode, wParam, lParam)
        End If

        'Extract the keyboard structure from the lparam
        'This will contain the virtual key and any flags.
        'This is using the my.computer.keyboard to get the
        'flags instead
        Dim KeyboardSruct As KBDLLHOOKSTRUCT = Marshal.PtrToStructure(lParam, GetType(KBDLLHOOKSTRUCT))

        If KeyboardSruct.vkCode = Vk_Tab And My.Computer.Keyboard.AltKeyDown Then
            'Alt Tab
            Return 1
        ElseIf KeyboardSruct.vkCode = Vk_Escape And My.Computer.Keyboard.CtrlKeyDown Then
            'Control Escape
            Return 1
        End If

        'Send the message along 
        Return CallNextHookEx(HookId, nCode, wParam, lParam)

    End Function

    Public Shared Sub Jam()
        'Add the low level keyboard hook
        If HookId = 0 Then
            HookDelegate = AddressOf KeyBoardHookProc
            HookId = SetWindowsHookEx(Wh_Keyboard_LL, HookDelegate, Marshal.GetHINSTANCE(Assembly.GetExecutingAssembly.GetModules()(0)), 0)

            If HookId = 0 Then
                'error
            End If

        End If
    End Sub

    Public Shared Sub UnJam()
        'Remove the hook
        UnhookWindowsHookEx(HookId)
    End Sub

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall)> _
    Private Shared Function CallNextHookEx( _
       ByVal idHook As Integer, _
       ByVal nCode As Integer, _
       ByVal wParam As IntPtr, _
       ByVal lParam As IntPtr) As Integer
    End Function

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall, SetLastError:=True)> _
     Private Shared Function SetWindowsHookEx( _
           ByVal idHook As Integer, _
           ByVal HookProc As HookCallback, _
           ByVal hInstance As IntPtr, _
           ByVal wParam As Integer) As Integer
    End Function

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall, SetLastError:=True)> _
    Private Shared Function UnhookWindowsHookEx(ByVal idHook As Integer) As Integer
    End Function

    Private Structure KBDLLHOOKSTRUCT
        Public vkCode As Integer
        Public scanCode As Integer
        Public flags As Integer
        Public time As Integer
        Public dwExtraInfo As IntPtr
    End Structure

End Class

Reply to this topic

Be a part of the DaniWeb community

We're a friendly, industry-focused community of developers, IT pros, digital marketers, and technology enthusiasts meeting, networking, learning, and sharing knowledge.

nemzmiyaw 0 Newbie Poster · Answer 1 · 2011-04-13T09:40:36+00:00

wow this work like a charm
Thank You Unhnd_Exception you are great mark this solved.

phyrons 0 Newbie Poster · Answer 2 · 2011-04-24T06:02:01+00:00

Exelent!, Works for me with WINDOWS 7 and VB.net 2008

to block Win Key add :

Private Const VK_LWinKey As Integer = 91
Private Const VK_RWinKey As Integer = 92

and

...
ElseIf KeyboardSruct.vkCode = VK_LWinKey Or KeyboardSruct.vkCode = VK_RWinKey Then
   'Left Windows Key o Rigth Windows Key
   Return 1
End If

cj101 0 Newbie Poster · Answer 3 · 2011-04-27T21:06:20+00:00

Here is my edit on this code. Although the Ctrl Alt Del doesnt get stopped like I thought it would. Using VB 2010 .NET4

Imports System.Runtime.InteropServices
Imports System.Reflection

Public Class Form1
    Private Sub Form1_HandleCreated(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.HandleCreated
        KeyboardJammer.Jam()
    End Sub

    Private Sub Form1_HandleDestroyed(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.HandleDestroyed
        KeyboardJammer.UnJam()
    End Sub
End Class

Public Class KeyboardJammer

    Private Delegate Function HookCallback(ByVal nCode As Integer, ByVal wParam As Integer, ByVal lParam As IntPtr) As Integer
    Private Shared HookDelegate As HookCallback
    Private Shared HookId As Integer
    Private Const Wh_Keyboard_LL As Integer = 13
    Private Const Vk_Tab As Integer = 9
    Private Const Vk_Escape As Integer = 27
    Private Const vk_Del As Integer = 46
    Private Const Vk_F4 As Integer = 115
    Private Const VK_LWinKey As Integer = 91
    Private Const VK_RWinKey As Integer = 92

    Private Shared Function KeyBoardHookProc(ByVal nCode As Integer, ByVal wParam As Integer, ByVal lParam As IntPtr) As Integer
        'All keyboard events will be sent here.

        'Don't process just pass along.
        If nCode < 0 Then
            Return CallNextHookEx(HookId, nCode, wParam, lParam)
        End If

        'Extract the keyboard structure from the lparam
        'This will contain the virtual key and any flags.
        'This is using the my.computer.keyboard to get the
        'flags instead
        Dim KeyboardSruct As KBDLLHOOKSTRUCT = Marshal.PtrToStructure(lParam, GetType(KBDLLHOOKSTRUCT))
        MsgBox(KeyboardSruct.vkCode.ToString, MsgBoxStyle.OkOnly)
        If KeyboardSruct.vkCode = Vk_Tab And My.Computer.Keyboard.AltKeyDown Then
            'Alt Tab
            Return 1
        ElseIf KeyboardSruct.vkCode = Vk_Escape And My.Computer.Keyboard.CtrlKeyDown Then
            'Control Escape
            Return 1
        ElseIf KeyboardSruct.vkCode = VK_LWinKey Or KeyboardSruct.vkCode = VK_RWinKey Then
            'Left Windows Key or Rigth Windows Key
            Return 1
        ElseIf KeyboardSruct.vkCode = vk_Del And My.Computer.Keyboard.CtrlKeyDown And My.Computer.Keyboard.AltKeyDown Then
            'Ctrl Alt Del
            Return 1
        ElseIf KeyboardSruct.vkCode = Vk_F4 And My.Computer.Keyboard.AltKeyDown Then
            'Alt F4
            Return 1
        End If

        'Send the message along 
        Return CallNextHookEx(HookId, nCode, wParam, lParam)

    End Function

    Public Shared Sub Jam()
        'Add the low level keyboard hook
        If HookId = 0 Then
            HookDelegate = AddressOf KeyBoardHookProc
            HookId = SetWindowsHookEx(Wh_Keyboard_LL, HookDelegate, Marshal.GetHINSTANCE(Assembly.GetExecutingAssembly.GetModules()(0)), 0)

            If HookId = 0 Then
                'error
            End If

        End If
    End Sub

    Public Shared Sub UnJam()
        'Remove the hook
        UnhookWindowsHookEx(HookId)
    End Sub

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall)> _
    Private Shared Function CallNextHookEx( _
       ByVal idHook As Integer, _
       ByVal nCode As Integer, _
       ByVal wParam As IntPtr, _
       ByVal lParam As IntPtr) As Integer
    End Function

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall, SetLastError:=True)> _
    Private Shared Function SetWindowsHookEx( _
           ByVal idHook As Integer, _
           ByVal HookProc As HookCallback, _
           ByVal hInstance As IntPtr, _
           ByVal wParam As Integer) As Integer
    End Function

    <DllImport("user32.dll", CharSet:=CharSet.Auto, CallingConvention:=CallingConvention.StdCall, SetLastError:=True)> _
    Private Shared Function UnhookWindowsHookEx(ByVal idHook As Integer) As Integer
    End Function

    Private Structure KBDLLHOOKSTRUCT
        Public vkCode As Integer
        Public scanCode As Integer
        Public flags As Integer
        Public time As Integer
        Public dwExtraInfo As IntPtr
    End Structure

End Class

vebe.net · Answer 4 · 2012-02-12T18:11:48+00:00

Thanks for the code.
Its working good in form load, and form close event.
But in my kiosk application I have to Jam and Unjam multiple times.
When i hit Jam the second time it wont work.
I have tried to modify the code without any luck.
It would be nice if you have a solution to this.
Thank you.

OBijac 0 Newbie Poster · Answer 5 · 2012-02-19T19:24:06+00:00

Thanks for the code.
Its working good in form load, and form close event.
But in my kiosk application I have to Jam and Unjam multiple times.
When i hit Jam the second time it wont work.
I have tried to modify the code without any luck.
It would be nice if you have a solution to this.
Thank you.

I would also be interested in this because I have the same problem anjust can't figure it out...

I would appreciate any ideas, thx!

ranganaath 0 Newbie Poster · Answer 6 · 2012-10-19T21:11:17+00:00

ranganaath 0 Newbie Poster

12 Years Ago

thanks

ranganaath 0 Newbie Poster · Answer 7 · 2012-10-19T21:12:50+00:00

ranganaath 0 Newbie Poster

12 Years Ago

How to disable Windowskey + Tab

Baldwin_1 0 Newbie Poster · Answer 8 · 2016-01-31T00:22:06+00:00

i saw that this is 4years ago but, thank you Unhnd_Exception for the source code.

i will put credits to him for my Internet Cafe Software...

and for those who is asking how to use it in 2 forms, like the 1st form will hook then opening the 2nd form it will not hook then switch back to 1st form and it will hook again...

Just change this:

Public Shared Sub UnJam()
        'Remove the hook
        UnhookWindowsHookEx(HookId)
    End Sub

to this

Public Shared Sub UnJam()
        'Remove the hook
        UnhookWindowsHookEx(HookId)
        HookId = 0
    End Sub

Your welcome ^_^

adeministrator 0 Newbie Poster · Answer 9 · 2016-02-02T22:47:36+00:00

adeministrator 0 Newbie Poster

8 Years Ago

do you have c# version?